Asistente de enfoque láser para Gigapan Epic

De todos es conocida las ventajas de la fotografía comúnmente llamada de “gigapixel”, donde a través de técnicas de imagen computacional, podemos construir una única imagen a partir de un mosaico de varias decenas, o cientos de imágenes.

Esta técnica es particularmente interesante para la fotografía de obras de arte y patrimonio cultural, ya que nos permite realizar una documentación o reproducción con un importante nivel de detalle.

Para ello, con el fin de alcanzar el máximo detalle posible, se suelen utilizar objetivos largos con el fin de maximizar el nivel de detalle. Sin, embargo al reducir el campo de visión, aumenta la probabilidad de encontrarnos con áreas de bajo contraste, textura y en definitiva, detalle que permita al autofoco trabajar con precisión.

Con el fin de superar esta situación, es común plantear un asistente de enfoque a través de un haz laser, que permitan “dibujar” una zona de alto contraste en el plano a enfocar.

De esta forma la lógica de este dispositivo sería: encender láser > enfocar > apagar láser > disparar

Una buena forma de desarrollar un dispositivo que realice esta lógica, es utilizar un microcontrolador del tipo Arduino, o en mi caso he utilizado un Theensy++, compatible con programación Arduino, por lo que el uso de uno u otro controlador es indiferente.

El diseño del circuito es realmente simple y requiere de pocos componentes:

• A.- Una placa Arduino, Theensy o similares
• B.- Dos optoacopladores 4N35
• C.- Algunas resistencias de 400Ω aprox.
• D.- Dos LED
• E.- Dos conectores Jack 2.5 hembra estéreo y uno mono
• F.-  Dos pulsadores.
• G.- Un láser tipo “cruz”

El fin de este artículo tiene la finalidad de plantear, en cierta manera, las bases de la interacción entre un Arduino y una cámara de fotos tipo DSLR.

Al utilizar equipos bastantes caros, como puede ser una cámara fotográfica DSLR, a nadie le gustaría arruinar su equipo realizando experimentos. Por eso, una de los elementos claves de este circuito son los optoacopladores o optoaislador, el cual es un pequeño circuito integrado, formado por un LED y un fototransistor. Su uso esta orientado a los circuitos lógicos, donde dos sistemas pueden ser perfectamente aislados a través de la señal lumínica producida por el LED y la excitación del fototransistor.

Por tanto gracias a los optoacopladores 4N35 podemos aislar, y activar tanto disparo como enfoque sin riesgos de dañar nuestra cámara.

Dado que un optqacoplador trabaja con un LED debemos tomar ciertas precauciones en la intensidad de entrada, por lo que se suele preceder el optoacoplador con una resistencia de un valor más o menos alto. 

La conexión entre nuestra cámara y el optqacoplador lo tenemos que hacer mediante el cable de disparo correspondiente de nuestro equipo. Para ello yo he usado un latiguillo de Nikon DC-2 a Jack 2.5 de 3 pines. En términos de equipos fotográficos el conector de audio Jack de 2.5 fue adoptado por Canon bajo el nombre de E3, y actualmente es usado con frecuencia como un estándar entre cámara y diversos dispositivos como mandos a distancia, intervalómetros, etc…

De igual forma la conexión entre nuestro GigaPan Epic Pro y el Arduino, la he realizado con un conector del tipo Jack 2.5mm (Canon E3), suministrado por dicha marca como conector para ciertos dispositivos de Canon.

Otro elemento de este circuito es el un Laser, del tipo cruz, o cruceta, que nos permita crear un área de suficiente contraste como para asegurar nuestro foco sobre superficies de escaso contraste o textura. Dado que nuestro microcontralador, probablemente trabaje sobre los 5V, hay que asegurarse que nuestro Laser trabaje con esta tensión.

El resto de los elementos como pulsadores y LED los he introducido para probar la secuencia de disparo, y mantener encendido el LED con el fin de poderlo alinear con el punto de enfoque.

A continuación el código fuente:

/**********************
Asistente laser de enfoque y disparo
by Jose Pereira / www.jpereira.net 
**********************/

// salidas control
int shutterPin = 18;
int focusPin = 19;
int laserPin = 20;


//salidas LED
int power = 22;
int ledShutterPin = 25;

// entradas control
int testBtPinLaser = 3;
int testBtPinLaserFocusShoot = 4;
int gigapanInputPin = 0;

//retrasos

int shutterPressDelay = 1000;
int focusPressDelay = 3000;
int laserOfDelay = 1000;


void setup(){
  
  Serial.begin(9600);
  digitalWrite(LED_BUILTIN, HIGH);
  
  //salidas Control
  pinMode(shutterPin, OUTPUT);
  pinMode(focusPin, OUTPUT);
  pinMode(laserPin, OUTPUT);
  
  //salidas LED
  pinMode(power, OUTPUT);
  pinMode(ledShutterPin, OUTPUT);
  
  //Entradas 
  pinMode(testBtPinLaser, INPUT_PULLUP);
  pinMode(gigapanInputPin, INPUT_PULLUP );
  pinMode(testBtPinLaserFocusShoot, INPUT_PULLUP);
  
  //enciende LED de encendido
  digitalWrite(power, HIGH);
  
}

void laserON(){
  digitalWrite(laserPin, HIGH);
  //digitalWrite(ledLaserPin, HIGH);
}

void laserOFF(){
  digitalWrite(laserPin, LOW);
  //digitalWrite(ledLaserPin, LOW);
}


void focusON(){
  digitalWrite(focusPin, HIGH);
  digitalWrite(power, LOW);
  //digitalWrite(ledFocusPin, HIGH);
  delay(focusPressDelay);
  
}

void focusOFF(){
  digitalWrite(focusPin, LOW);
  digitalWrite(power, HIGH);
  //digitalWrite(ledFocusPin, LOW);
}

void shoot(){
  laserON();
  focusON();  
  laserOFF();
  delay(laserOfDelay);
  digitalWrite(ledShutterPin, HIGH);
  delay(1000);
  digitalWrite(shutterPin, HIGH);
  delay(shutterPressDelay);
  digitalWrite(shutterPin, LOW);
  digitalWrite(ledShutterPin, LOW);
  focusOFF();

}


void loop() {
  
  if (digitalRead(testBtPinLaser) == LOW) {
    laserON();
    delay(5000);
    laserOFF();
   
  }
  
 if (digitalRead(testBtPinLaserFocusShoot) == LOW) {
   shoot();
  }
   
  if (digitalRead(gigapanInputPin) == LOW) {
   shoot();
  }
  
}